#Grammatical Relation grasping for Spanish
*STRUCTLIMIT s
*DEFAULTATTR tag

*DUAL
=subject_np/subject_of
"ART" 2:"NC|NP" "ADJ|ADV|PREP|PDEL|N.*|ART"* "PPX.*"{0,2} 1:"V.fin"

*DUAL
=object/object_of
"V.fin"? 1:"VL.*" "ART"? "ADJ|ADV"{0,2} 2:"N.*" 

#"V.fin"? 1:"VL.*" [lemma="a"] "ART"? "ADJ|ADV"{0,2} 2:"N.*"
#Direct objects in Spanish take the preposition 'a' when the N is animate (je!)
#But resutls of this query contain too much noise

=object_inf
"V.fin"? 1:"VL.*" 2:"VLinf"
		
#some modal verbs are not properly identified and are included here. Anyway, maybe it's too noisy?

=object_clause
"V.fin"? 1:"VL.*" "CQUE" "ART"? "N.*"? 2:"V.fin"

#it works pretty nicely

=predicate
1:"VSfin" "ADV"? 2:"ADJ"
1:"VSfin" "ART"? "N."
			
#predicative complements of 'ser' clauses

=adj_complement
1:"VSfin" "ADV"? "ADJ" [lemma="de"] 2:"VLinf"  

*DUAL		
=n_modifier/modifies
1:"N." "ADV"? 2:"ADJ"
#like compounds
1:"N." [lemma="de"] 2:"N."  
#this is less certain
1:"N." [lemma="de"] "ART" 2:"N." 
		

*SYMMETRIC
=y_o
1:"NC" "ADJ|ADV"* [lemma="y|o"] "ART"? "ADJ|ADV"* 2:"NC"
1:"V.*" "ADJ|ADV"* [lemma="y|o"]"ADJ|ADV"* 2:"V.*"
1:"ADJ" [lemma="y|o"] "ADV"? 2:"ADJ"

#simple cases of coordination for NP's and VERB's